Sub connected ( $KeyFlags,$id )
	UserGroupFromFile( "admins", "./admin.txt" );

	### Set initial values for left/right and top/bottom coordinates ###
	$left_right_connected = 29;
	$top_bottom_connected = 50;
	### End ###

	openPrivButton( "connect_screen_bg",$left_right_connected,$top_bottom_connected,142,100,5,-1,16,"");
	FOR ($i=1;$i<=32;$i=$i+1)
		IF ($user_array[$i,1] != "")
		THEN
		  openPrivButton ("player_".$i."_number",$left_right_connected+1,$top_bottom_connected+1,5,5,5,-1,32,$i);
		  openPrivButton ("player_".$i."_nickname",$left_right_connected+7,$top_bottom_connected+1,25,5,5,-1,32,$user_array[$i,5]);
		  IF ( $user_array[$i,6] == 0)
		  THEN
		    openPrivButton ("player_".$i."_status",$left_right_connected+33,$top_bottom_connected+1,15,5,5,-1,32,"^2Ready");
		  ELSE
		    IF ( $user_array[$i,6] == 1)
		    THEN
		      openPrivButton ("player_".$i."_status",$left_right_connected+33,$top_bottom_connected+1,15,5,5,-1,32,"^1Not ready");
		    ELSE
		      IF ( $user_array[$i,6] == 2)
		      THEN
		        openPrivButton ("player_".$i."_status",$left_right_connected+33,$top_bottom_connected+1,15,5,5,-1,32,"^3Spectator");
		      ELSE
		        openPrivButton ("player_".$i."_status",$left_right_connected+33,$top_bottom_connected+1,15,5,5,-1,32,"");
		      ENDIF
		    ENDIF
		  ENDIF
		  IF( UserInGroup( "admins",GetCurrentPlayerVar("UserName") ) == 1 )
		  THEN
		    IF ($user_array[$i,7] == 1 )
		    THEN
		      openPrivButton ("p_exit_".$user_array[$i,1],$left_right_connected+49,$top_bottom_connected+1,10,5,5,-1,32,"^2p_exit",pit_exit);
		    ELSE
		      openPrivButton ("p_exit_".$user_array[$i,1],$left_right_connected+49,$top_bottom_connected+1,10,5,5,-1,32,"^7p_exit",pit_exit);
		    ENDIF

		    IF ($user_array[$i,8] == 1 )
		    THEN
		      openPrivButton ("s_qual_".$user_array[$i,1],$left_right_connected+60,$top_bottom_connected+1,10,5,5,-1,32,"^2s_qual",start_qual);
		    ELSE
		      openPrivButton ("s_qual_".$user_array[$i,1],$left_right_connected+60,$top_bottom_connected+1,10,5,5,-1,32,"^7s_qual",start_qual);
		    ENDIF
		  ENDIF
		ELSE
		  closePrivButton ("player_".$i."_number&player_".$i."_nickname&player_".$i."_status");
		ENDIF

		### Raise $top_bottom_connected with 5 before drawing next button
		$top_bottom_connected=$top_bottom_connected+5;
		### End ###

		### When player 16 is reached, change value of $left_right_connected to start next colum. Set $top_bottom_connected to initial value ###
		IF ($i == 16)
		THEN
		  $left_right_connected = 100;
		  $top_bottom_connected = 50;
		ENDIF
		### End ###
	ENDFOR

	openPrivButton( "refresh_connected",69,144,20,5,10,10,32,"^3Refresh (%cpt%)",connected );
	openPrivButton( "close_connected",90,144,20,5,10,-1,32,"^3Close",close_connected );
	
	IF( UserInGroup( "admins",GetCurrentPlayerVar("UserName") ) == 1 )
	THEN
	  openPrivButton( "reset_connected",111,144,20,5,10,-1,32,"^3Reset",reset_connected );
	ENDIF
EndSub

Sub close_connected ( $KeyFlags,$id )
	closePrivButton ("connect_screen_bg&refresh_connected&reset_connected&close_connected");
	FOR ($i=1;$i<=32;$i=$i+1)
		closePrivButton ("player_".$i."_number&player_".$i."_nickname&player_".$i."_status");
		closePrivButton ("p_exit_".$user_array[$i,1]);
		closePrivButton ("s_qual_".$user_array[$i,1]);
	ENDFOR
EndSub

Sub reset_connected ( $KeyFlags,$id )
	FOR ($i=1;$i<=32;$i=$i+1)
		IF ($user_array[$i,1] != "")
		THEN
		  $user_array[$i,6]=1;
		  $user_array[$i,7]=0;
		  $user_array[$i,8]=0;
		ENDIF
	ENDFOR
	connected( 0,0 );
EndSub

Sub set_player_status ( $KeyFlags, $argv )
	$status_array[1,0] = "^2Ready";
	$status_array[1,1] = "^1Not ready";
	$status_array[1,2] = "^3Spectator";
	
	FOR ($i=1;$i<=32;$i=$i+1)
		IF ($user_array[$i,1] == GetCurrentPlayerVar ("UserName") )
		THEN
		  IF ($argv >=0 && $argv <= 2)
		  THEN
		    PrivMsg ("^7Status was: " . $status_array[1,$user_array[$i,6]+0]);
		    $user_array[$i,6] = $argv;
		    PrivMsg ("^7Status is set to: " . $status_array[1,$argv+0]);
		  ELSE
		    IF ($argv == "" )
		    THEN
		      PrivMsg ("^7Current status is: " . $status_array[1,$user_array[$i,6]+0]);
		    ELSE
		      PrivMsg ("^7Status can be:");
		      PrivMsg ("^70 = ^2ready^7 , 1 = ^1not ready^7 , 2 =^3spectator");
		    ENDIF
		  ENDIF
		ENDIF
	ENDFOR
EndSub

Sub pit_exit ( $KeyFlags, $id )
	$id = Substr($id,7);
	FOR ($i=1;$i<=32;$i=$i+1)
		IF ($id == $user_array[$i,1] )
		THEN
		  $user_array[$i,7] = 1;
		  cmdLFS ("/msg ^3Go to pitlane exit: " . $user_array[$i,5] );
		ENDIF
	ENDFOR
	cmdLFS ("/rcm ^2Go to pitlane exit and prepare for qualify");
	cmdLFS ("/rcm_ply " . $id);
	connected( 0,0 );
EndSub

Sub start_qual ( $KeyFlags, $id )
	$id = Substr($id,7);
	FOR ($i=1;$i<=32;$i=$i+1)
		IF ($id == $user_array[$i,1] )
		THEN
		  $user_array[$i,8] = 1;
		  cmdLFS ("/msg ^3Start qualify: " . $user_array[$i,5] );
		ENDIF
	ENDFOR
	cmdLFS ("/rcm ^2Start qualify");
	cmdLFS ("/rcm_ply " . $id);
	connected( 0,0 );
EndSub